Recipe 11.8 Finding the Site Links for a Site

11.8.1 Problem

You want to list the site links that are associated with a site.

11.8.2 Solution

11.8.2.1 Using a graphical user interface

Open LDP and from the menu, select Connection Connect.
For Server, enter the name of a domain controller (or leave blank to do a serverless bind).
For Port, enter 389.
Click OK.
From the menu, select Connection Bind.
Enter credentials of domain user.
Click OK.
From the menu, select Browse Search.
For BaseDN, type the Inter-Site Transports container DN (e.g., cn=Inter-siteTransports,cn=sites,cn=configuration,dc=rallencorp,dc=com).
For Scope, select Subtree.

For Filter, enter the following:

(&(objectcategory=siteLink)(siteList=cn=<SiteName>,[RETURN]
cn=sites,cn=configuration,<ForestRootDN>))

Click Run.

11.8.2.2 Using a command-line interface

> dsquery * "cn=inter-site transports,cn=sites,cn=configuration,<ForestRootDN>"[RETURN]
-filter "(&(objectcategory=siteLink)(siteList=cn=<SiteName>,[RETURN]
cn=sites,cn=configuration,<ForestRootDN>))" -scope subtree -attr name

11.8.2.3 Using VBScript

' This code displays the site links associated with the specified site
' ------ SCRIPT CONFIGURATION ------
strSiteName = "<SiteName>"  ' e.g. Raleigh
' ------ END CONFIGURATION ---------

set objRootDSE = GetObject("LDAP://RootDSE")
strSiteDN = "cn=" & strSiteName & ",cn=sites," & _
            objRootDSE.Get("ConfigurationNamingContext")

strBase    =  "<LDAP://cn=Inter-site Transports,cn=sites," _
              & objRootDSE.Get("ConfigurationNamingContext") & ">;"
strFilter  = "(&(objectcategory=siteLink)" & _
             "(siteList=" & strSiteDN & "));" 
strAttrs   = "name;"
strScope   = "subtree"

set objConn = CreateObject("ADODB.Connection")
objConn.Provider = "ADsDSOObject"
objConn.Open "Active Directory Provider"
set objRS = objConn.Execute(strBase & strFilter & strAttrs & strScope)

WScript.Echo "Total site links for " & strSiteName & ": " & objRS.RecordCount
if objRS.RecordCount > 0 then
   objRS.MoveFirst
   while Not objRS.EOF
       Wscript.Echo vbTab & objRS.Fields(0).Value
       objRS.MoveNext
   wend
end if

11.8.3 Discussion

A site can be included as part of zero or more site links. A site with no site links would be considered orphaned from the site topology, since there is no way to determine how and where it connects into the topology. Branch office sites may have only a single site link back to a hub, while a hub site may have numerous links that connect it to the rest of the world.

Finding the site links associated with a site consists of performing a query for all siteLink objects that have DN of the site included in the siteList attribute for a link. The siteList attribute is a multivalued attribute that contains all the sites that are connected via the site link.